simple good inno script for vst plugin

[nickb100]

[Setup]
AppName=Plugin
AppVerName=Plugin
AppPublisher=Developer
DefaultDirName={pf32}\Plugin
DisableProgramGroupPage=yes
OutputDir=out
OutputBaseFilename=
Compression=lzma2
SolidCompression=yes
VersionInfoVersion=1.0.0
VersionInfoDescription=
WizardImageFile=WizardImage.bmp
WizardSmallImageFile=WizardSmallImage.bmp
SetupIconFile=Icon.ico

[Types]
Name: full; Description: Full installation
Name: custom; Description: Custom installation; Flags: iscustom

[Components]
Name: vst; Description: VST2; Types: full
Name: vst3; Description: VST3; Types: full
Name: vst64; Description: VST2 64 bit; Types: full; Check: IsWin64
Name: vst364; Description: VST3 64 bit; Types: full; Check: IsWin64

[Files]
Source: data\*; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs
Source: 32\Plugin.dll; DestDir: "{code:GetVST}"; Components: vst; Flags: ignoreversion
Source: 32\Plugin.vst3; DestDir: "{cf32}\VST3"; Components: vst3; Flags: ignoreversion
Source: 64\Plugin.dll; DestDir: "{code:GetVST64}"; Components: vst64; Flags: ignoreversion
Source: 64\Plugin.vst3; DestDir: "{cf64}\VST3"; Components: vst364; Flags: ignoreversion

[UninstallDelete]
Name: {app}; Type: filesandordirs

Code: Select all

var 
Page1: TInputDirWizardPage;
Page2: TInputDirWizardPage;

procedure InitializeWizard;
begin
    Page1 := CreateInputDirPage(wpSelectComponents, 'VST Folder 32 - bit', 
    'Please Select Your VST Directory', 
    '', 
    False, 'New Folder'); 
    Page1.Add('VST directory'); 
    Page1.Values[0] := ExpandConstant('{pf32}\Vstplugins'); 
     
    Page2 := CreateInputDirPage(wpSelectComponents, 'VST Folder 64 - bit', 
    'Please Select Your VST Directory', 
    '', 
    False, 'New Folder'); 
    if IsWin64 then Page2.Add('VST directory'); 
    if IsWin64 then Page2.Values[0] := ExpandConstant('{pf64}\Vstplugins'); 
end;
 
function GetVST(Param: String): String; 
begin 
  Result := Page1.Values[0]; 
end;

function GetVST64(Param: String): String; 
begin 
  Result := Page2.Values[0]; 
end; 

function ShouldSkipPage(PageID: Integer): Boolean;
begin
  case PageID of
    Page1.ID : Result := not IsComponentSelected('vst');
    Page2.ID : Result := not IsComponentSelected('vst64');
  else
    Result := False;
  end;
end;